gistfile1.txt

#!/usr/bin/env raku
use v6.d;
$*OUT.out-buffer = False;   # Autoflush

# Advent of Code 2024 day 19 -- https://adventofcode.com/2024/day/19

class TowelArranger
{
    has @.towels;
    has @.designs;

    method count-possible($design)
    {
        state %cache = '' => 1;
        return %cache{$design} //=
                @!towels.grep({ ($design.index($_) // -1) == 0 })
                        .map({ self.count-possible($design.substr(.chars)) })
                        .sum;
    }

    method count-possible-designs { @!designs.grep({ self.count-possible($_) }).elems }
    method count-possible-ways { @!designs.map({ self.count-possible($_) }).sum }
}

sub MAIN(IO() $inputfile where *.f = 'aoc19.input')
{
    my ($towels, $blank, @designs) = $inputfile.lines;
    my @towels = $towels.comb(/\w+/);
    my $ta = TowelArranger.new(:@towels, :@designs);

    say "Part 1: $ta.count-possible-designs() designs are possible.";
    say "Part 2: $ta.count-possible-ways() ways to make a design.";
}