next-jdbc-handle-duplicate-key.clj

(defmulti exception->map
  (fn [^SQLException e]
    (.getSQLState e)))

(defn- remove-quotes [s]
  (clojure.string/replace s #"\"" ""))

(defn sql-key->keyword [sql-key]
  (-> sql-key
      (string/replace #"_key$" "")
      (string/replace-first #"_" "/")
      (string/replace #"_" "-")
      (keyword)))

(defn sql-error->sql-key [sql-error]
  (remove-quotes (re-find #"\".*\"" sql-error)))

;; Postgres unique_violation
;; https://www.postgresql.org/docs/9.2/errcodes-appendix.html
(defmethod exception->map "23505" [^SQLException e]
  {:duplicate-key
   (-> (.getMessage e)
       (sql-error->sql-key)
       (sql-key->keyword))})

(defmethod exception->map :default [^SQLException e]
  (println "Unhandled SQL execption "
           (.getSQLState e) "\n "
           (.getMessage e))
  {:unknown [(.getSQLState e)]})

;; Usage:

(try
  (jdbc/execute-one! *database* (sql/format form))
  (catch Exception e
    ;; This will return {:duplicate-key :some-table/some-key} if the exception is a 23505 error.
    (exception->map e)))