rainbow donut

rainbowDonut.pde

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.png");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 480;        
float shutterAngle = .4;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(32);
  noStroke();
  pixelDensity(1);
  colorMode(HSB, 1);
}

float x, y, z, tt;
int N = 720;
float R = 160, r = 80, th, ph;

void thing(float q) {
  noFill();
  strokeWeight(4);
  beginShape();
  for (int i=0; i<N; i++) {
    th = TWO_PI*i/N;
    ph = 4*th + TWO_PI*q - 3*TWO_PI*t;
    
    x = R + r*cos(ph);
    y = 0;
    z = r*sin(ph);
    
    xx = x*cos(th);
    yy = x*sin(th);
    zz = z;
    
    stroke(q, 1, br(xx,yy,zz));
    vertex(xx,yy,zz);
  }
  endShape(CLOSE);
}

float xx, yy, zz;

float br(float x_, float y_, float z_){
  return constrain(map(modelZ(x_,y_,z_),-R,R,0,1.3),.05,1);
}

void draw_() {
  background(.05); 
  push();
  translate(width/2, height/2);
  rotateY(-TWO_PI*t);
  for (int i=0; i<8; i++)
    thing(i*1.0/8);
  pop();
}

gif: https://twitter.com/beesandbombs/status/905827763327823878