Updated PKGBUILD for HotDoc 0.8.103

PKGBUILD-hotdoc.sh

# Copyright 2018 Google LLC

# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at

#     http://www.apache.org/licenses/LICENSE-2.0

# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

# Maintainer: Aleksey Filippov <[email protected]>
# Contributor: Lubosz Sarnecki <[email protected]>
pkgname=hotdoc
pkgver=0.8.103
pkgrel=1
epoch=
pkgdesc='HotDoc: the tastiest API documentation system'
arch=(i686 x86_64)
url=https://github.com/hotdoc/hotdoc
license=(LGPL)
depends=(
	'python-cchardet'
	'python-dbus-deviation'
	'python-decorator'
	'python-networkx-1.11'
	'python-pkgconfig-1.1.0'
	'python-setuptools'
    'python-lxml'
    'python-schema'
    'python-sqlalchemy'
    'python-toposort'
    'python-wheezy'
    'python-yaml'
)
makedepends=(cmake flex git npm)
checkdepends=()
optdepends=()
provides=()
conflicts=()
replaces=()
backup=()
options=()
install=
changelog=
source=("git+https://github.com/${pkgname}/${pkgname}.git#tag=${pkgver}")
noextract=()
sha256sums=('SKIP')
validpgpkeys=()

prepare () {
  cd "${pkgname}"

  # We need to patch the version comparator here because while Arch Linux
  # provides a package for the exact version, its metadata lists it as being
  # version 1.0 (without the .167).
  sed -e 's/wheezy\.template==0\.1\.167/wheezy.template~=0.1/' \
      -i setup.py

  # This script uses the Python 2.x "print" statement. It looks like upstream
  # has not yet converted it to Python 3.x but fortunately 2to3 works well.
  2to3 -w hotdoc/hotdoc_dep_printer.py
}

build() {
  cd "$pkgname"
  python setup.py build
}

package() {
  cd "$pkgname"
  python setup.py install --root="$pkgdir/" --optimize=1
}