protocol.ohm

Protocol {
  Item = 
    | Constant
    | Model
    | Enum
    
  Property = ident ":" Type
    
  Model = "model" ident "{" ListOf<Property, ";"> "}"
        
  Constant = 
    | GenericConstant<ArrayType, Array>
    | GenericConstant<EnumName, EnumValue>
    | GenericConstant<StringType, string>
    | GenericConstant<NumberType, number>
    | GenericConstant<BooleanType, boolean>
  GenericConstant<T, E> = "const" Property "=" E ";"
    
  Type = 
    | RecordType
    | ArrayType
    | EnumName
    | NumberType
    | StringType
    | BooleanType
    
  RecordType = Type "{}"  
  ArrayType = Type "[]"
  
  StringType = "string"
  BooleanType = "boolean"

  Array = "[" ListOf<primitive, ","> "]"
    
  Enum = "enum" EnumName "{" ListOf<ident, ","> "};"
  EnumValue = EnumName "." ident
  EnumName = upper+ alnum*

  NumberType = 
   	|  "i8" |  "u8" 
    | "i16" | "u16" 
    | "i32" | "u32" 
    | "i64" | "u64" 
    | "f32" | "f64"
    
  ident  (an identifier)
    = letter alnum*
    
  primitive = 
    | number
    | string
    | boolean

  boolean = "true" | "false"

  string //TODO use string definition from es5 grammar
    = "\"" alnum* "\""
 
  number
    = digit* "." digit+ -- decimal
    | digit+            -- integer
}