plogue-plugins PKGBUILD

PKGBUILD

# Maintainer: Katie Wolfe <~kt/[email protected]>
# Updated by ThePython10110
pkgname=('plogue-aria' 'plogue-chipspeech' 'plogue-chipsounds' 'plogue-sforzando' 'plogue-tablewarp2')
pkgbase=plogue-plugins
pkgver='1.982~beta1'
debver='1.982~beta1'
dirver='1.982beta1'
license=('custom')
pkgrel=1
epoch=1
pkgdesc="Plogue audio plugins, beta Linux port (unofficial support, DO NOT report bugs upstream!)"
arch=('x86_64')
url="https://plogue.com"
options=('!strip')
install=plogue-plugins.install
source_x86_64=(
	"https://sforzando.s3.us-east-1.amazonaws.com/LINUX_plogue-sforzando_${pkgver}_x86_64.zip"
	"https://chipsounds.s3.us-east-1.amazonaws.com/LINUX_plogue-chipsounds_${pkgver}_x86_64.zip"
	"https://chipspeech.s3.us-east-1.amazonaws.com/LINUX_plogue-chipspeech_${pkgver}_x86_64.zip"
)
noextract=()
sha512sums_x86_64=('9a8203054c512c1a24028f117354512a36aba6f50a445dafafc3e4ca7a4fdc99edd4fdfe9833055acaefed855bef1a952cf9c20e635263cfdefcc9ce0abca92e'
                   'fda1542e9deb64cd36ec5af469e8d25efafc8c1b9eb60fc4c9d31e129f221491b26e4301c1f1084ab7a8a84db7ebbbb9537d3a08efde3f8bff1fd4737f44f35f'
                   'a60bda99428e3c4a4efbe723059fa0c6134e7e9647223da089645b70230062a6349e5ca2c72af8f269b887d4bd101fd12ccd789cb2fbd06635932243a58bc6a0')

dirs=('chipsounds' 'chipspeech' 'sforzando')
debs=('aria' 'chipsounds' 'chipspeech' 'sforzando' 'tablewarp2')

prepare() {
  mkdir -p debs
  for d in "${dirs[@]}"; do
    cp "LINUX_plogue-${d}_${dirver}_x86_64/"*.deb debs
  done
	for p in "${debs[@]}"; do
		mkdir -p "plogue-$p"
		cd "plogue-$p"
    ar x "../debs/plogue-${p}_${debver}_amd64.deb"
		cd ..
	done
}

package_plogue-aria() {
	# from deb: libgtk-3-0,libglib2.0-0,libpango-1.0-0,libcairo2,libpangocairo-1.0-0,curl
	depends=('gtk3' 'glib2' 'pango' 'cairo' 'curl' 'zenity')
	optdepends=('libsndfile: Adds support for more audio formats')

	dopkg
}

dopkg() {
	tar -C "${pkgdir}" -xJf "$pkgname/data.tar.xz"
	install -Dm 644 "${pkgdir}/usr/share/doc/${pkgname}/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
}
package_plogue-chipspeech() {
	depends=('plogue-aria')
	dopkg
}
package_plogue-chipsounds() {
	depends=('plogue-aria')
	dopkg
}
package_plogue-sforzando() {
  depends=('plogue-aria' 'gtkmm3')
	dopkg
}
package_plogue-tablewarp2() {
	depends=('plogue-aria')
	dopkg
}