Utility methods to find nodes by class

scene_util.gd

## Returns the first child node of a given class.
## If deep_search is true, search the whole tree below this node.
static func find_child_with_class(root: Node, type: Variant, deep_search: bool = false) -> Node:
	if not is_instance_valid(root):
		return null

	if is_instance_of(root, type):
		return root

	var candidates: Array[Node] = root.get_children()
	while not candidates.is_empty():
		var candidate: Node = candidates.pop_back()
		if is_instance_of(candidate, type):
			return candidate
		if deep_search:
			candidates.append_array(candidate.get_children())

	return null


## Returns every child node of a given class.
## If deep_search is true, search the whole tree below this node.
static func find_children_with_class(root: Node, type: Variant, deep_search: bool = false) -> Array:
	var result: Array = []
	if is_instance_of(root, type):
		result.push_back(root)

	var candidates: Array[Node] = root.get_children()
	while not candidates.is_empty():
		var candidate: Node = candidates.pop_back()
		if is_instance_of(candidate, type):
			result.push_back(candidate)
		if deep_search:
			candidates.append_array(candidate.get_children())

	return result


## Returns the closest ancestor node with the given class
static func find_ancestor_with_class(root: Node, type: Variant) -> Node:
	var parent: Node = root.get_parent()
	while is_instance_valid(parent):
		if is_instance_of(parent, type):
			return parent
		parent = parent.get_parent()
	return null