consult.el function to find files using macOS Spotlight

consult-spotlight.el

(defun consult--mdfind-builder (input)
  "Build command line from INPUT."
  (pcase-let ((`(,arg . ,opts) (consult--command-split input)))
    (unless (string-blank-p arg)
      (cons (append '("mdfind") (list arg) opts)
            (apply-partially #'consult--highlight-regexps 
                            (mapcar #'regexp-quote (split-string arg)) 
                            t)))))

(defun consult-mdfind (&optional initial)
  "Search with `mdfind` for files which match input given INITIAL input.

The input is passed directly to the mdfind process. The search is started
asynchronously, similar to `consult-grep`. See `consult-grep` for more
details regarding the asynchronous search."
  (interactive)
  (find-file (consult--read
              (consult--process-collection #'consult--mdfind-builder
                :transform (consult--async-map (lambda (x) (string-remove-prefix "./" x)))
                :highlight t :file-handler t)
              :prompt "Spotlight Search: "
              :sort nil
              :require-match t
              :initial initial
              :add-history (thing-at-point 'filename)
              :category 'file
              :history '(:input consult--find-history))))