Working example for particle.io photon

tempPublish.h

// Use this include for the Web IDE:
#include "OneWire/OneWire.h"

// Use this include for Particle Dev where everything is in one directory.
// #include "OneWire.h"

// This library can be tested on the Core/Photon by running the below
// DS18x20 example from PJRC:

// OneWire DS18S20, DS18B20, DS1822 Temperature Example
//
// http://www.pjrc.com/teensy/td_libs_OneWire.html
//
// The DallasTemperature library can do all this work for you!
// http://milesburton.com/Dallas_Temperature_Control_Library

// from the publishme example at 
// https://community.particle.io/t/tutorial-getting-started-with-spark-publish/3422
unsigned long lastTime = 0UL;

OneWire ds(D0);  // on pin D0 (a 4.7K resistor is necessary)

const int ADDR_LEN = 8;
char s[ADDR_LEN*2 + 1];
char tempBuff[64];


void setup(void) {
  Serial.begin(57600);
  Particle.publish("BootUp", "I came on line");
}

void loop(void) {
  // from publishme
  unsigned long now = millis();
    
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[ADDR_LEN];
  unsigned char* addr_c = addr;
  float celsius, fahrenheit;

  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    
    // now is in milliseconds
    unsigned nowSec = now/1000UL;
    unsigned sec = nowSec%60;
    unsigned min = (nowSec%3600)/60;
    unsigned hours = (nowSec%86400)/3600;
    sprintf(s,"%u:%u:%u",hours,min,sec);
    Particle.publish("Uptime",s);
    
    delay(10250);
    return;
  }

  Serial.print("ROM =");
  for( i = 0; i < ADDR_LEN; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();

  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  }

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end

  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.

  present = ds.reset();
  ds.select(addr);
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
  
  strcpy(s,"");
  Serial.println("Printing address tmp");
  for(i=0; i<ADDR_LEN; i++){
      char temp[3];
      sprintf(temp, "%02x", addr[i]);
      strcat(s,temp);
  }
  Serial.print("s: ");
  Serial.println(s);

  sprintf(tempBuff, "%f", fahrenheit);  //assuming fahrenheit is a float variable
  Particle.publish(s, tempBuff);
}